Cette approche est antérieure à celle de M. Rydel. Ses principales caractéristiques sont décrites dans les communications et notes d'application suivantes :
[B23] F. Broydé, "Modélisation et simulation des circuits à tubes avec IsSpice3", Electronique Radio Plans, No. 553, décembre 1993, pp. 69-73.
[X6] F. Broydé, Ch. Hymowitz, "Modeling Vacuum Tubes, part I", Intusoft Newsletter, February 1994, pp. 6-11.
[X7] F. Broydé, Ch. Hymowitz, "Modeling Vacuum Tubes, part II", Intusoft Newsletter, April 1994, pp. 7-11.
[B44] F. Broydé, E. Clavelier, Ch. Hymowitz, "Comments on "Spice Models of Vacuum-tube Amplifiers"", Journal of the Audio Engineering Society, vol. 45, No. 6, June 1997, pp. 490-491.
Ces références sont citées dans les articles :
Nous n'avons pas particulièrement cherché à développer des modèles correspondant à des tubes audio courants selon cette approche. Elle était (et est toujours) destinée à la création de modèles de tubes de puissance, que nous ne pouvons présenter ici. Cependant, nous produisons ci-dessous la version orginale commentée de la bibliothèque extubes.lib, datant de 1993, qui montre les principes retenus, et qui est prévue pour fonctionner avec les simulateurs SPICE de la société Intusoft.
******************
Library EXTUBES.LIB
ver 1.3
October 9, 1993
EXCEM
12, Chemin des Hauts de Clairefontaine
78580 MAULE
FRANCE
tel 33 (1) 34 75 13 65
fax 33 (1) 34 75 13 66
THIS SAMPLE LIBRARY IS INTENDED FOR EVALUATION PURPOSE ONLY !
*******************
.SUBCKT 12AU7_1 1 2 3 4 5
* Anode Grid Cathode F F'
* COPYRIGHT EXCEM, 1993
*
* This is a model for 12AU7, without parameter fitting, with heater model.
*
X1 1 2 3 10 TRIO1 {SFS=0.7 VBIG=-0.9 VBIA=-1.3 MU=17 RMU=0.5 VMU=-20
+ SFMU=1.6 K=827E-6 RK=0.08 VK=-20 SFK=1.6 SIGMAG=0.05 ALPHAG=5.2 SFG=3.5}
*
X2 4 5 10 HEAT1 {INOM=0.15 VNOM=6.3 LAMBDA=1 RCOOL=3 TCTE=10 TNOM=1150
+ INITT%=100 W=2.045 ISAT=0.099}
*
C2 1 2 1.5P
C3 3 1 0.5P
C4 2 3 1.6P
C5 3 4 4P
C6 3 5 4P
*
.ENDS
*******************
.SUBCKT 12AU7_2 1 2 3 4 5
* Anode Grid Cathode F F'
* COPYRIGHT EXCEM, 1993
*
* This is a model for 12AU7, without parameter fitting, the heater
* beeing only a resistor.
*
X1 1 2 3 10 TRIO1 {SFS=0.7 VBIG=-0.9 VBIA=-1.3 MU=17 RMU=0.5 VMU=-20
+ SFMU=1.6 K=827E-6 RK=0.08 VK=-20 SFK=1.6 SIGMAG=0.05 ALPHAG=5.2 SFG=3.5}
*
R1 4 5 42
V1 10 0 0.099
*
C2 1 2 1.5P
C3 3 1 0.5P
C4 2 3 1.6P
C5 3 4 4P
C6 3 5 4P
*
.ENDS
*******************
.SUBCKT EL9000_1 1 2 3 4 5 6
* Anode Grid2 Grid1 Cathode F F'
* COPYRIGHT EXCEM, 1993
*
* This is a model for an hypothetical pentode, with heater model.
*
X1 1 2 3 4 10 PENT1 {SFS=0.7 VBIG=-0.9 VBIA=-1.3 MUG2=17 MUA=15000
+ RMU=0.5 VMU=-20 SFMU=1.6 K=5.4E-3 RK=0.08 VK=-20 SFK=1.6
+ SIGMA1=0.05 ALPHA1=5.2 SFG1=3.5 SIGMA2=0.12 ALPHA2=0.06 SFG2=2.3
+ VCCR=0.58 SFVC=0.33}
*
X2 5 6 10 HEAT1 {INOM=0.15 VNOM=6.3 LAMBDA=1 RCOOL=3 TCTE=10 TNOM=1150
+ INITT%=100 W=2.045 ISAT=0.690}
*
C2 1 2 1.5P
C3 3 1 0.5P
C4 2 3 1.6P
C5 3 4 4P
C6 3 5 4P
*
.ENDS
*******************
.SUBCKT EL9000_2 1 2 3 4 5 6
* Anode Grid2 Grid1 Cathode F F'
* COPYRIGHT EXCEM, 1993
*
* This is a model for a hypothetical pentode, the heater beeing only
* a resistor.
*
X1 1 2 3 4 10 PENT1 {SFS=0.7 VBIG=-0.9 VBIA=-1.3 MUG2=17 MUA=15000
+ RMU=0.5 VMU=-20 SFMU=1.6 K=5.4E-3 RK=0.08 VK=-20 SFK=1.6
+ SIGMA1=0.05 ALPHA1=5.2 SFG1=3.5 SIGMA2=0.12 ALPHA2=0.06 SFG2=2.3
+ VCCR=0.58 SFVC=0.33}
*
R1 5 6 42
V1 10 0 0.099
*
C2 1 2 1.5P
C3 3 1 0.5P
C4 2 3 1.6P
C5 3 4 4P
C6 3 5 4P
*
.ENDS
*******************
.SUBCKT TRIO1 A G C ISAT
*
* COPYRIGHT EXCEM, 1993
*
* forward and reverse condition are treated in this triode model
* as well as saturation.
* the model describes only the static bahaviour of the triode, and
* neglects secondary emission (that would occur at high VG and low VA).
*
* THE TRIODE'S 14 PARAMETERS ARE:
*
* SFS shape factor of the saturation law.
* VBIG contact potential of the grid
* (the voltage above which current grid may start to flow).
* VBIA contact potential of the anode.
* MU amplification factor at slighly negative grid voltage.
* RMU reduction factor for MU at very negative grid voltage.
* VMU grid voltage for mid-range MU (negative).
* SFMU shape factor for MU reduction law.
* K perveance at slightly negative grid voltage.
* RK perveance reduction factor at very negative grid voltage.
* VK grid voltage for mid-range perveance (negative).
* SFK shape factor for perveance reduction law.
* SIGMAG effective cross-section of the grid relative to the anode.
* ALPHAG grid current amplification factor.
* SFG shape factor of the grid current law.
*
B1 15 0 V=V(G)-V(C)<-1P ?
+ {K}*(1+{RK}*((V(G)-V(C))/{VK})^{SFK})/(1+((V(G)-V(C))/{VK})^{SFK}) : {K}
* V(15) is the effective perveance
B2 16 0 V=V(G)-V(C)<-1P ? {MU}*(1+{RMU}*((V(G)-V(C))/{VMU})^{SFMU})
+ /(1+((V(G)-V(C))/{VMU})^{SFMU}) : {MU}
* V(16) is the effective MU
B4 9 0 V=V(G)-V(C)-{VBIG}+(V(A)-V(C)-{VBIA})/(V(16)+1U)
B6 10 0 V=V(9)>0 ? V(15)*V(9)^1.5/(V(ISAT)+1P) : 0
B7 12 0 V=V(10)<{SFS} ? V(10)*(V(ISAT)+1P) :
+ (V(ISAT)+1P)*({SFS}+(V(10)-{SFS})*{1-SFS}/({1-2*SFS}+V(10)))
* B7 contains an arbitrary saturation law modeled by the shape factor SFS
* to match the available data. SFS should be between 0 and 1, and the
* lower SFS the softer the change of slope in the saturation law.
*
B8 14 0 V=V(A)-V(C)>{VBIA+0.1M} ? (V(A)-V(C)-{VBIA})/{ALPHAG} : 2P
B9 28 0 V=V(G)-V(C)>{VBIG+0.1M} ? V(14)>1P ? ((V(G)-V(C)-{VBIG}
+ +{SIGMAG^(1/SFG)}*V(14))/(V(G)-V(C)-{VBIG}+V(14)))^{SFG} : 0
B10 8 0 V=V(G)-V(C)<0 ?
+ V(28)*(({VBIG+10U}+V(C)-V(G))/{VBIG+10U}) : V(28)
B15 G C I=V(8)*V(12)
B17 A C I=(1-V(8))*V(12)
*
.ENDS
*******************
.SUBCKT PENT1 A G2 G1 C ISAT
*
* COPYRIGHT EXCEM, 1993
*
* forward and reverse condition are treated in this model
* as well as saturation.
* the model describes only the static bahaviour of the pentode, and
* neglects secondary emission. It is assumed that G2 is always very
* positive with respect to the cathode.
*
*
* THE PENTODE'S 20 PARAMETERS ARE:
*
* SFS shape factor of the saturation law.
* VBIG contact potential of the grids G1 and G2
* (the voltage above which current grid may start to flow).
* VBIA contact potential of the anode.
* MUG2 amplification factor for G2 at slighly negative G1 voltage.
* MUA amplification factor for A at slightly negative G1 voltage.
* RMU reduction factor for MU at very negative G1 voltage.
* VMU grid voltage for mid-range MU (negative).
* SFMU shape factor for MU reduction law.
* K perveance at slightly negative G1 voltage.
* RK perveance reduction factor at very negative G1 voltage.
* VK grid voltage for mid-range perveance (negative).
* SFK shape factor for perveance reduction law.
* SIGMA1 effective cross-section of G1 relative to the anode and G2.
* ALPHA1 grid G1 current amplification factor.
* SFG1 shape factor of the grid G1 current law.
* SIGMA2 effective cross-section of G2 relative to the anode.
* ALPHA2 grid G2 current amplification factor.
* SFG2 shape factor of the grid G2 current law.
* VCCR virtual cathode current ratio.
* SFVC shape factor of the virtual cathode current law.
*
*
B1 15 0 V=V(G1)-V(C)<-1U ? {K}*(1+{RK}*((V(G1)-V(C))/{VK})^{SFK})
+ /(1+((V(G1)-V(C))/{VK})^{SFK}) : {K}
* V(15) is the effective perveance
B2 16 0 V=V(G1)-V(C)<-1U ? (1+{RMU}*((V(G1)-V(C))/{VMU})^{SFMU})
+ /(1+((V(G1)-V(C))/{VMU})^{SFMU}) : 1
* V(16) is the factor used to establish both effective MU coefficient
E1 17 0 16 0 {MUG2}
E2 18 0 16 0 {MUA}
* V(17) is the effective MUG2 and V(18) is the effective MUA
B4 9 0 V=V(G1)-V(C)-{VBIG}+(V(A)-V(C)-{VBIA})/
+ (V(18)+1U)+(V(G2)-V(C))/(V(17)+1U)
B6 10 0 V=V(9)>1P ? V(15)*V(9)^1.5/(V(ISAT)+1P) : 0
B7 12 0 V=V(10)<{SFS} ? V(10)*(V(ISAT)+1P) :
+ (V(ISAT)+1P)*({SFS}+(V(10)-{SFS})*{1-SFS}/({1-2*SFS}+V(10)))
* B7 contains an arbitrary saturation law modeled by the shape factor SFS
* to match the available data. SFS should be between 0 and 1, and the
* lower SFS the softer the change of slope in the saturation law.
*
B8 14 0 V=V(G2)-V(C)+{MUG2/MUA}*(V(A)-V(C))>0.1M ?
+ V(G2)-V(C)+{MUG2/MUA}*(V(A)-V(C))/{ALPHA1} : 0.2M
B9 28 0 V=V(G1)-V(C)>{VBIG+10U} ? V(14)>0.1M ? ((V(G1)-V(C)-{VBIG}
+ +{SIGMA1^(1/SFG1)}*V(14))/(V(G1)-V(C)-{VBIG}+V(14)))^{SFG1} : 0
B10 8 0 V=V(G1)-V(C)<0 ?
+ V(28)*(({VBIG+10U}+V(C)-V(G1))/{VBIG+10U}) : V(28)
B11 21 0 V=V(A)-V(C)>{VBIA+0.1M} ? (V(A)-V(C)-{VBIA})/{ALPHA2} : 0.2M
B12 32 0 V=V(G2)-V(C)>{VBIG+10U} ? V(21)>0.1M ? ((V(G2)-V(C)-{VBIG}
+ +{SIGMA2^(1/SFG2)}*V(21))/(V(G2)-V(C)-{VBIG}+V(21)))^{SFG2} : 0
B13 22 0 V=V(G2)-V(C)<0 ?
+ V(32)*(({VBIG+10U}+V(C)-V(G2))/{VBIG+10U}) : V(32)
*
B14 23 0 V=V(22)-{SIGMA2}>1P ?
+ V(12)*(1-{VCCR}*(V(22)-{SIGMA2})^{SFVC}) : V(12)
* when the virtual cathode is present, this factor describes the
* decrease in cathode current (see Terman p 192).
B15 G1 C I=V(8)*V(23)
R15 G1 C 100MEG
B16 G2 C I=(1-V(8))*V(22)*V(23)
R16 G2 C 100MEG
B17 A C I=(1-V(8))*(1-V(22))*V(23)
R17 A C 100MEG
*
.ENDS
*******************
.SUBCKT HEAT1 F F' ISAT
*
* COPYRIGHT EXCEM, 1993
*
* this model for the heater gives a voltage ISAT
* that is analog to the saturation current of the cathode.
*
*
* THE HEATER'S 9 PARAMETERS ARE:
*
* INOM the nominal heater current, at nominal voltage.
* VNOM the nominal heater voltage (causing nominal temperature)
* LAMBDA temperature coefficient of the heater resistance.
* (normalized to the nominal temperature);
* RCOOL resistance of the cold heater.
* TCTE the time constant for the heater temperature.
* TNOM the nominal heater temperature in K.
* INITT% initial heater temperature in % of TNOM
* W work function of the heater, in eV.
* ISAT the saturation current at nominal heater voltage.
*
V1 F 4 0
R1 5 4 0.01
* above the Debye temperature, the resistivity is nearly linear
* with respect to temperature, see Ashcroft & Mermin p 525 and p 461.
B1 5 F' V=V(7)>0 ? I(V1)*({VNOM/INOM-RCOOL}*(1+{LAMBDA}*(V(7)-1))+{RCOOL})
+ : I(V1)*{VNOM/INOM}
* B1 delivers the power received by the heater
B2 6 0 V=(V(F)-V(F'))*I(V1)>0 ? (V(F)-V(F'))*I(V1)/{VNOM*INOM} : 1
R2 6 7 1
C1 7 0 {TCTE} IC={INITT%/100}
* we consider only conductive dissipation, and
* V(7) is therefore a normalized temperature.
* B4 contains the Richardson-Duschman law, with an exponential containing
* B=W/k, the Bolzmann's constant being 0.8617e-4 eV/K
* for Tungsten (see Ashcroft & Mermin p 364) W=4.5 eV, and it may
* be 2.2 times lower for an oxide-coated cathode (see Terman p 173).
* B3 delivers the saturation current
E1 13 0 7 0 {TNOM}
B3 ISAT 0 V=V(13)>0 ?
+ {ISAT}*V(7)^2*exp({W/.8417E-4}*(1/{TNOM}-1/(V(13)+1))) : {ISAT}
* the 1K added to V(13) avoids convergence problems.
.ENDS
******************
Retour à la page d'accueil |
Retour au Club Excem |
| URL : http://www.excem.fr/clubf/tubebr-f.htm | © Excem 2000, 2011 |
| Dernière mise à jour : 31 mai 2011 | Ecrire à : webmaster@excem.fr |